Mine sisu juurde

Küpsiste seaded

Vali iga liigi kohta, milliseid küpsiseid lubad. Oma valikut saad alati muuta iga lehe allosas oleva lingi „Küpsiste seaded“ kaudu. Privaatsuspoliitika

Vajalikud

Alati sees

Vajalikud sisselogimiseks, ostukorvi säilitamiseks ja sinu valikute meelespidamiseks. Need on alati sees.

Millised küpsised?
  • weboke_sessie, weboke_klant, weboke_remember: sinu seanss ja sisselogituks jäämine
  • weboke_basket: sinu ostukorv
  • wkBtwIncl: hindade näitamine koos käibemaksuga või ilma
  • wok_cookies: sinu küpsisevalik, 12 kuud

Mõõdab, milline reklaam viib külastuse või tellimuseni, et me ei maksaks reklaamide eest, mis midagi ei anna.

Millised küpsised?
  • Google Ads Google Tag Manageri kaudu (_gcl_au, _gcl_aw), kuni 90 päeva
  • OpenAI Ads, reklaamid ChatGPT-s
  • wok_aff: millise partneri kaudu meie juurde jõudsid (partnerprogramm), 60 päeva

4,6

Riik ja keel

Igal riigil on oma sait, selle riigi hindade ja käibemaksuga.

Vaata

Käibe summeerimine kuude või perioodide kaupa funktsiooniga SUMIFS

Kassaraamatus, müüginimekirjas või tööaja arvestuses on igal real kuupäev. Tegelikult tahad aga teada kogusummat kuu, kvartali või kahe kuupäeva vahelise perioodi kaupa, vajadusel ka toodete kaupa. Funktsiooniga SUMIFS ja kahe kuupäevatingimusega teed sellise ülevaate, mis jääb õigeks ka siis, kui ridu lisandub. Seda saab teha ka liigendtabeliga (vt Liigendtabel kuude, kvartalite või nädalate kaupa), kuid SUMIFS on mugavam, kui ülevaade peab säilitama kindla kuju, näiteks aruande või eelarve jaoks.

Näitena võtame lillepoe Bloemisterij Het Zonnetje müügi töölehel Verkoop: veerus A on kuupäev, veerus B toode, veerus C kategooria ja veerus D summa, ridadel 2 kuni 300.

1. samm: kuude rida

Loo tööleht Ülevaade. Kaheteistkümne kuupäeva tippimise asemel teeb ühe valem need kõik. Tipi lahtrisse A2:

=EDATE(DATE(2026;1;1);SEQUENCE(12;1;0))

SEQUENCE(12;1;0) loob arvud 0 kuni 11 ja EDATE liidab nii mitu kuud 1. jaanuarile 2026. Saad iga kuu esimese päeva lahtritesse A2 kuni A13. Anna vahemikule A2:A13 kohandatud vorming mmmm yyyy (menüüst More formats (rohkem vorminguid), Custom (kohandatud), vt Kohandatud numbrivormingud: „12 tk“, summad tuhandetes, negatiivsed punaselt), siis on lahtrites jaanuar 2026, veebruar 2026 ja nii edasi.

Kuupäevavorming mmmm yyyy
Kohandatud vorming mmmm yyyy näitab kuu nime täielikult koos aastaga

2. samm: käive kuude kaupa

Tipi lahtrisse B2:

=SUMIFS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0))

SUMIFS liidab summad, mille kuupäev on suurem kui kuu esimene päev või sellega võrdne, ja väiksem kui kuu viimane päev või sellega võrdne (EOMONTH argumendiga 0 annab sama kuu lõpu). Lohista valem lahtrini B13 või vali enne tippimist B2:B13 ja lõpeta klahvidega Ctrl+Enter.

3. samm: toodete kaupa

Pane tootenimed päistena kõrvuti, näiteks Rozen lahtrisse C1, Tulpen lahtrisse D1 ja Boeket lahtrisse E1, ning tipi lahtrisse C2:

=SUMIFS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0);Verkoop!$B$2:$B$300;C$1)

Lisandub üks tingimuste paar: toode peab võrduma päisega. Pane tähele dollarimärke: $A2 lukustab kuude veeru, C$1 päiste rea. Tänu sellele saab sama valem olla kogu vahemikus. Kiirelt: vali kõigepealt C2:E13, tipi valem ja vajuta Ctrl+Enter. Euro-Office paneb valemi siis kõigisse valitud lahtritesse ja kohandab viited iga lahtri jaoks.

Käive kuude ja toodete kaupa
Summeeritud kuude ja toodete kaupa. Valemiribal on lahtri C2 valem, mis vaatab viitega C$1 päist Rozen (1)

Loendamine summeerimise asemel

Müükide arvu kuus loendad samade tingimustega funktsiooniga COUNTIFS:

=COUNTIFS(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0))

Vabalt valitud periood

Pane alguskuupäev lahtrisse H1 ja lõppkuupäev lahtrisse I1. Käive nende vahel, mõlemad päevad kaasa arvatud:

=SUMIFS(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Levinud vead

  • Jutumärgid ja &: võrdlus on jutumärkides ja lahter tuleb selle järele märgiga &: ">="&H1. Kui tipid ">=H1", otsib Euro-Office teksti H1 ja tulemus on 0.
  • Kellaajaga kuupäevad (16-11-2026 14:32) jäävad kuu viimasel päeval tingimusest "<="&EOMONTH(...) välja, sest see on südaöö. Kasuta siis teise tingimusena "<"&EDATE($A2;1): väiksem kui järgmise kuu esimene päev.
  • Ainult kuu numbri järgi filtreerimine, näiteks abiveerus funktsiooniga MONTH(), liidab jaanuari 2025 ja jaanuari 2026 kokku. Võta aasta alati arvesse.
  • Tekstina salvestatud kuupäevad ei lähe arvesse. Vt Kuupäevad, mis tulevad sisse tekstina või mille päev ja kuu on omavahel vahetatud.

Hetk…

Seadista oma domeenid

Määra iga domeeni jaoks nimeserverid, seos sinu majutusega ja kes saab omanikuks.

Laadin sinu domeene…