Mine sisu juurde

Küpsiste seaded

Vali iga liigi kohta, milliseid küpsiseid lubad. Oma valikut saad alati muuta iga lehe allosas oleva lingi „Küpsiste seaded“ kaudu. Privaatsuspoliitika

Vajalikud

Alati sees

Vajalikud sisselogimiseks, ostukorvi säilitamiseks ja sinu valikute meelespidamiseks. Need on alati sees.

Millised küpsised?
  • weboke_sessie, weboke_klant, weboke_remember: sinu seanss ja sisselogituks jäämine
  • weboke_basket: sinu ostukorv
  • wkBtwIncl: hindade näitamine koos käibemaksuga või ilma
  • wok_cookies: sinu küpsisevalik, 12 kuud

Mõõdab, milline reklaam viib külastuse või tellimuseni, et me ei maksaks reklaamide eest, mis midagi ei anna.

Millised küpsised?
  • Google Ads Google Tag Manageri kaudu (_gcl_au, _gcl_aw), kuni 90 päeva
  • OpenAI Ads, reklaamid ChatGPT-s
  • wok_aff: millise partneri kaudu meie juurde jõudsid (partnerprogramm), 60 päeva

4,6

Riik ja keel

Igal riigil on oma sait, selle riigi hindade ja käibemaksuga.

Vaata

Kahe loendi võrdlemine: kes on ühes loendis, aga mitte teises?

Liikmete loend maksete vastu, eelmise aasta kliendid selle aasta omade vastu, laoseis tellimuse vastu: tahad teada, kes on ühes loendis, aga mitte teises. Dubleerivate klientide leidmine ja eemaldamine otsib duplikaate ühe loendi sees; siin võrdled kahte loendit omavahel.

Näiteks võtame pagariäri Bakkerij De Korenaar kahe töölehega: Klanten2025, kus on eelmise aasta e-posti aadressid lahtrites A2:A8, ja Klanten2026, kus on selle aasta aadressid lahtrites A2:A7.

1. viis: abiveerg sõnadega lahkus või jääb

Kirjuta töölehel Klanten2025 lahtrisse B2:

=IF(COUNTIF(Klanten2026!$A$2:$A$7;A2)=0;"lahkus";"jääb")

Lohista valem alla kuni viimase kliendini. COUNTIF loendab, mitu korda aadress 2026. aasta loendis esineb. Kui tulemus on 0, on klient lahkunud. Seejärel saad veeru B järgi filtreerida või sortida (vt Sortimine ja filtreerimine).

Dollarimärgid on olulised: ilma nendeta nihkub teise loendi vahemik allalohistamisel kaasa ja ülemised aadressid jäävad vahemikust välja.

2. viis: loend ainult erinevustest

Eraldi töölehel koostab FILTER korraga loendi kõigist lahkunud klientidest:

=FILTER(Klanten2025!A2:A8;COUNTIF(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"keegi ei lahkunud")

Siin saab COUNTIF teiseks argumendiks terve loendi ja loendab iga 2025. aasta aadressi korraga. FILTER jätab alles aadressid, mille puhul tulemus on 0. Uued kliendid leiad, kui loendid ümber vahetad:

=FILTER(Klanten2026!A2:A7;COUNTIF(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"uusi pole")

Lahkunud ja uued kliendid kõrvuti
Lahkunud kliendid (1) ja uued kliendid (2), kumbki ühe FILTER-valemiga

Need, kes on ainult ühes kahest loendist, olgu uued või lahkunud, saad valemiga:

=UNIQUE(VSTACK(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

VSTACK paneb kaks loendit üksteise alla. UNIQUE, mille kolmas argument on 1, jätab alles ainult väärtused, mis esinevad täpselt ühe korra. Kui mõni aadress on juba ühe loendi sees topelt, muuda see loend enne unikaalseks: =UNIQUE(VSTACK(UNIQUE(Klanten2025!A2:A8);UNIQUE(Klanten2026!A2:A7));;1).

3. viis: värvid loendite asemel

  1. Vali töölehel Klanten2025 aadressid, A2:A8.
  2. Vali vahekaardil Home (Avaleht) Conditional formatting (tingimusvorming), New rule (uus reegel), tüüp Formula (valem).
  3. Kirjuta =COUNTIF(Klanten2026!$A$2:$A$7;$A2)=0, vali täitevärv ja klõpsa OK.

Viide teisele töölehele vormindusreeglis töötab Euro-Office'is probleemideta; Exceli vanemates versioonides tuli selleks kasutada nimega vahemikku.

Lahkunud kliendid värvitud
Aadressid, mida 2026. aastal enam pole, värvuvad oranžiks; veerg B näitab, kas klient lahkus või jääb

Lõksud

  • Tühikud: "info@dekorenaar.nl " koos tühikuga lõpus on arvutustabeli jaoks teine aadress. Eemalda tühikud kõigepealt abiveerus funktsiooniga TRIM.
  • Tühjad lahtrid vahemikus loetakse samuti väärtuseks. Võta seega ainult andmetega read või filtreeri tühjad lahtrid välja tingimusega <>"".
  • Arvud vs tekst: kui võrdled kliendinumbreid ja ühes loendis on number tekstina (lahtris vasakul) ning teises arvuna, siis need omavahel kokku ei lähe. Vt VLOOKUP annab veateate #N/A: nii lahendad selle.
  • Kirjuta UNIQUE kolmandaks argumendiks TRUE või 1, mitte tõlgitud sõna; Euro-Office tunneb ainult ingliskeelseid nimesid (vt Exceli valemite ülevõtmine: ingliskeelsed funktsioonide nimed ja semikoolon).

Hetk…

Seadista oma domeenid

Määra iga domeeni jaoks nimeserverid, seos sinu majutusega ja kes saab omanikuks.

Laadin sinu domeene…